Make/N=100/D/O w1,w2,w3; Edit w1,w2,w3; // wave3つ作成，編集 (D:倍精度，O:上書き許可)
  w1=x // w1に0,1,2...という数字データを入力
  w2=w1*100; w3=1/(w1+1); // wave同士の操作
  Display w2 vs w1; Display w3 vs w1; // ついでにグラフ表示

  print w3[5]; // 「ウェーブw3のn番目のポイントの値」は，w3[n]と表す

1次元の場合と同様ですが，ウェーブの次数が異なる時（例えば，行列の特定の行や列を
1次元ウェーブとして取り出す等）は，例のようにp,q,r,sを使用します．
ウェーブ間で行数が異なる時も注意が必要です．配列の宣言で大きさ不足の時の
ような動作をする事があります．
行列について，Igorマニュアルの Multidimensional Wave Assignment に詳細な情報があります．

  Make/N=(3,5)/D/O wm; Edit wm; // 3x5の行列を作成しテーブルに表示
  wm[2][3]=10 // 行列wmの(2,3)の位置に数値10を入力
  wm=0 // 行列wmの全てのマスに0を入力
  wm[1][]=1 // 行列wmの「行」が1のマス全てに1を入力
  wm[][3]=2 // 行列wmの「列」が3のマス全てに2を入力

  Make/N=5/D/O w; Edit w; // テスト用に1次元waveを作っておく
  wm=x*10+y // 行列に適当な数を入力しておく
  w=wm[1][p] // 行列wmの行1を1次元wave「w」に入力（横1列を縦に）
  w=wm[p][2] // 行列wmの列2を1次元wave「w」に入力（縦1列を縦に）
  wm[1][]=w[q] // 1次元wave「w」を行列wmの行1に入力（縦を横1列に）
  wm[][2]=w[p] // 1次元wave「w」を行列wmの列2に入力（縦を縦1列に）

  Make/N=2/D/O w1; w1=1; Duplicate/O w1 w2,w3,w4,w5,w6,w7,w8,w9,w10,w11,w12;
  w2[1]=2;w3[1]=3;w4[1]=4;w5[1]=5;w6[1]=6;w7[1]=7;w8[1]=8;w9[1]=9;w10[1]=10;w11[1]=11;w12[1]=12;
  Display w1,w2,w3,w4,w5,w6,w7,w8,w9,w10,w11,w12;
  ModifyGraph rgb(w2)=(0,12800,52224),rgb(w3)=(0,39168,0),rgb(w4)=(65280,21760,0);
  ModifyGraph rgb(w5)=(52224,34816,0),rgb(w6)=(52224,52224,0),rgb(w7)=(16384,65280,16384);
  ModifyGraph rgb(w8)=(0,52224,52224),rgb(w9)=(0,34816,52224),rgb(w10)=(16384,28160,65280);
  ModifyGraph rgb(w11)=(29440,0,58880),rgb(w12)=(52224,0,41728);

  Make/N=(100,100)/D/O wm; Edit wm // 100×100の行列を作る
  wm=sin(x*0.1)+0.5*cos(y*0.2) // 適当な値を作成
  Display;AppendMatrixContour wm // 等高線プロット
  SetScale/P x 0,0.01,"m", wm; SetScale/P y 0,0.01,"m" // x,yのスケール調整

  Make/N=10000/D wx,wy,wz; Edit wx,wy,wz; // 10000ポイントのwaveを3つ作る
  wx=trunc(x/100); wy=x-100*trunc(x/100); wz=sin(wx*0.1)+0.5*cos(wy*0.2)
  Display;AppendXYZContour wz vs {wx,wy}

  Make/N=1000/D/O w; w=cos(x/10)+1; Display w; // テスト用wave作成
  WaveStats w // wave「w」の統計情報
  WaveStats/Q w; print V_avg // 平均値のみ表示
  WaveStats/R=[510,520] w // ポイント510-520の範囲の統計
  WaveStats/R=[510,] w // ポイント510以降の範囲の統計
  WaveStats/R=[pcsr(A),pcsr(B)] w // Ctrl-Iで表示しdrag&dropしたカーソル範囲の統計

  Make/N=5/D/O w1; Display w1; ModifyGraph mode=3; w1=x+0.3*sin(x*10); // テスト用wave作成
  CurveFit/NTHR=0 line w1 /D // y=a*x+bでフィッティング（「回帰分析」メニューからの操作と同じ）
  Edit W_coef // フィッティング結果を確認

係数の一部を固定したフィッティング

  Make/N=5/D/O mask; mask=1; mask[2]=0; mask[3]=0; Edit mask; // マスク用wave作成
  CurveFit/NTHR=0 line w1 /M=mask /D // [2][3]は除外してフィッティング

  Make/N=10/D/O w2; Display w2; ModifyGraph mode=3; w2=3*x^2+2*x+1; // テスト用wave作成
  FuncFit/NTHR=0 ftest W_coef w2 /D // フィッティングの実行

3. Igorマクロの例
3-1. なぜマクロか
マクロを利用すると，ルーチン作業（例：多数のファイルからデータを読み込む，類似処理を多数のデータに施す，一般的なウィンドウ操作，データのオフセットやゲインの調整，グラフ作成，統計やフーリエ変換等の処理，グラフのレイアウト表示や印刷等）や複数の処理等を自動化して効率よく作業が行えます．

3-2. 簡単なマクロの使い方
Igor上で，ウィンドウ-プロシージャウィンドウ-プロシージャウィンドウを選択します．
Procedureと書かれたウィンドウが現れるので，以下のテキストを追加します．

Macro test1()
print "macro test"
EndMacro

プロシージャウィンドウの下にある「コンパイル」ボタンを押し，メニューバーの「マクロ」をクリックすると，「test1」というマクロが作成されています．「test1」を選択すると実行され，コマンドウィンドウに macro test と表示されるはずです．

3-3. マクロの作成方法と動かし方
Igorでは，3-2のように，テキストをプロシージャウインドウに記述する事でマクロを作成します．また，Igorは拡張子が.ipfのテキストファイルをマクロとして認識します．保存（ファイル-プロシージャのコピーを保存）されたマクロファイルのアイコンをエクスペリメントファイル上に放り込むと，マクロとして認識されます．

マクロを動作させるには，3-2のようにメニューから選択する他に，コマンドラインに test1() のように入力してもOKです．

一つのマクロファイルには，異なる名前の複数のマクロを記述する事が出来ます．
従って，以下のマクロ例を，次々とプロシージャファイルに追加して大丈夫です．

3-4. 書式の約束ごと
♦マクロの最初と最後
マクロは，マクロ名を宣言する Macro **** 行から始まり，EndMacro の行で終了します．

♦コメントアウト
// 以降，改行までマクロに無視されます．
日本語の倍角文字が//の直後に続くとエラーとなるため，//の前後には半角スペースを
入れた方が無難です．

♦マクロの高速化
次項の変数宣言の後に
silent 1; pauseupdate;
と書く事で，マクロ実行中のコマンドライン表示とグラフとテーブルの再描写が抑制され，
高速動作するようになります．

♦文字変数と数字変数
数字と文字の変数は，最初にそれぞれ variable と string で宣言してから使用します．
最初のMacro行の後に空行があるとエラーが出ます．
変数としての文字は""なし，文字通りの文字列は""でくくって扱います．
Macro test2()
variable n1;
string name1;
n1=1; name1="nametest";
print n1,name1,"name1"; // "name1"はそのまま文字が表示される．
EndMacro

♦ウェーブの扱い
マクロ中でウェーブを扱う時は，ウェーブ名の文字列の最初に$を付けます．
また，変数を使って表したウェーブ同士の演算を行う時は，全体を()でくくります．
Macro test3()
string name1,name2,name3;
Make/N=3/D/O w1,w2,w3;
name1="w1";name2="w2";name3="w3";
print name1; Display $name1;
$name3=($name1)+($name2);
EndMacro

♦外部からの数字の入力（ファイル番号や処理の分岐等）
変数として test(n1)，test(n1,n2) 等としてカッコ内に variableを書いておくと，実行時
に開くダイアログで数字の入力が可能です．コマンドウィンドウから，test4(1,10) のよう
に直接数字を入力する事も出来ます．マクロ内で数字を具体的に記述した場合には，
そちらが優先されダイアログは開きません．
Macro test4(n1,n2)
variable n1,n2;
print n1,n2
EndMacro

♦文字の結合
外部入力した数字と文字等を結合してファイル名等を作成するには， file1=name1+".txt"; などとします． 数字と文字同士は結合出来ないので，あらかじめ name1=num2str(n1); と数字変数を文字変数に変換して file1=name1+".txt"; とするか，または file1=num2str(n1)+".txt"; のようにします．
例えば，TEK0001.csv という名前のデータファイルを変数を使って表すには "TEK000"+name1+".csv" となります．ファイル番号が9を超えてゼロが減る時は，後述のようにして扱う事が出来ます．
Macro test5(n1)
variable n1; string name1,file1;
name1=num2str(n1);
file1=name1+".txt";
print file1;
EndMacro

♦if文の基本書式と大小記号
Macro test6(n1)
variable n1;
if (n1<=0)
print "run";
else
print "not run";
endif
EndMacro

== equal
!= not-equal
< less than
<= less than or equal
> greater than
>= greater than or equal

複数の条件
if(a>1&&b==0)

♦do-while文
複数のファイル読み込みやグラフ描画等で使用します．
Macro test7()
variable n1,n2;
n1=1; n2=3;
do
print "macro test",n1;
n1+=1;
while(n1<=n2)
EndMacro

3-5. その他のコツなど
♦マクロ中の「;」
改行の代わりに「;」と書くと行の終わりとして扱われます．一行に複数行文の記述が可能になり，縦のスペースの節約が出来ます．
例： variable n1,n2; string name1,name2,name3,name4;

♦MacroとProc
Macroの代わりにProcを使うと，マクロメニューからは表示されなくなります．コマンドラインや別のマクロからの呼び出しは同様に使用する事が出来ます．
マクロが多すぎると「マクロ」メニューから表示されなくなる問題は，使用頻度の低いmacroをprocに変更する事で回避出来ます．

♦複数のMacroをまとめて動かすMacro
マクロを組み合わせて使用時（例えば，データロード，ゲイン調整，グラフ表示，印刷等のマクロを別々に作成しておき，まとめて動作させるマクロを別に作る等）に使用します．変数の受け渡しも可能です．
Macro test8(n1)
variable n1;
test5(n1);
test6(n1);
EndMacro

♦MacroとFunction
マクロは実行速度が速くありません．計算量の多いデータ解析をする時は，Functionとしてコンパイルさせた後に使用した方が遥かに実用的です．

♦上書き指定によるエラーの抑制など
マクロ中でファイルの複製作業を行うと，上書き防止のダイアログで処理が止まり，事前に消去が必要となり煩雑な事があります．
Duplicate/O data2 $name0;
のように /O オプションで上書き指定する事で回避出来ます．

また，WaveStats のようにデフォルトでコマンドラインに多くの文字をprintするコマンドは，WaveStats/Q のように /Q オプションで出力を減らす事が出来ます．
WaveStats/Q wave1; print V_avg

♦print コマンド
print は，FORTRAN の write(6,*) や C の printf と類似したコマンドです．コマンドラインやマクロ中で， print "test", 100 のようにコマンドラインに文字や数字や変数を出力する事が出来ます．マクロのバグ取り時に使用出来ます．

♦組み込み関数のテスト
printを使用した組み込み関数の動作例です．いずれもコマンドからの入力例と結果です．オプションなどの詳細は「リファレンス」に掲載されています．

print 1+2*3+2^3, exp(1), ln(e), log(10), cos(60*pi/180), asin(0.5)*180/pi, mod(60,7) // 数学演算
  15 2.71828 1 1 0.5 30 4

print Secs2Date(DateTime,0), Secs2Time(DateTime,3) // 日付と時刻の取得
  2100/01/01 12:15:05
    ちなみに，日付等の数字を文字変数に代入するには以下のようになります
    string dt,dy,dm,dd;
    dt=Secs2Date(DateTime,0);
    dy=dt[0,3]; dm=dt[5,6]; dd=dt[8,9];
    print dt,dy,dm,dd
        2100/01/01 2100 01 01

print trunc(1), trunc(1.2), trunc(-1.5) // 絶対値が小さい方向の最も近い整数を返します
  1 1 -1

print enoise(1) // -1〜1（可変）の範囲で一様な乱数を返します
  0.654505

♦グラフ表示について
マクロ中でグラフを表示させた時，規定の設定が反映されない事があります．
それらの設定と，凡例の書式例です．
Macro test3()
Display $name2, $name0, $name1, $name3;
ModifyGraph rgb($name1)=(0,0,65280),rgb($name2)=(0,39168,0),rgb($name3)=(44032,29440,58880);
ModifyGraph tick=2,mirror=1,minor=1;
Legend/C/N=text0/S=3/X=1.00/Y=1.00 "#"+num2str(n1)
EndMacro

データが多数で，「データ」−「ウェーブをロード」を繰り返すのが面倒な時，データロードを自動化するマクロです．指定したn1〜n2の番号のファイルをロードします．後半で，平均データを別waveに記録します．

多数のウィンドウに同じ処理（マーカを変更する，ラベルを付ける，legendを付ける，ShowInfoでカーソルを表示する，等）を施す時に使用出来ます．

手動でウィンドウを閉じる時，ダイアログが開き時間が掛かります．デフォルト名のグラフウィンドウを連続して閉じるマクロです．対応する番号が無い時は無視されるだけなので，例えばGraph11番以降を全て消したい時は，window_delete(11,1000) のようにコマンドに入力してもエラーは出ません．

次々とデータを取得する実験中に，自動でデータ処理を行うマクロです．
StartAutoBackground()を走らせておくと，一定時間（間隔[s] のところ）おきにFolderCheck()が実行されます．FolderCheck()は，指定したフォルダに新しい保存データがあるか（前回処理した番号より大きい番号のファイルが存在するか否か，です．次に処理すべきデータ番号をShotNum[0]に記録しています．）をチェックします．新しいデータを見付けた時には指定した処理を行います．この例では，Combine_auto()という外部マクロを実行します．外部マクロに，データ読み込みやグラフ表示等の適当なマクロを割り当てておけば，忙しい実験中でもIgorがデータ点をプロットしてある程度の解析を進めてくれます．
データファイルが大きく保存に時間が掛かる時，Igorがデータの存在を認識しても，まだ保存中で開けない事があります．この問題は，外部マクロの最初にwait_for_sec(2)などと書いておくと回避出来ます．
一定時間おきの動作を停止するためには，StopAutoBackground()を使用します．
フォルダ名，ファイル名や指定方法が環境に特化しています．詳細は，igormacro1をIgorで開いて，Jumbi()を実行した後でStartAutoBackground()を実行してみると分かり易いかもしれません．

WE7000でデータ保存に「バイナリ」を選択すると，*****.hdrというテキスト形式のヘッダファイルと*****.wvfというバイナリファイルが作成されます．ファイルサイズは，テキスト保存と比較して1/10程度に小さくなります．ヘッダファイルに書かれた時間分解能や電圧スケール等の情報を利用して，物理量に直したデータwaveを作成します．この例ではWE7273というモジュールの32chデータを処理していますので，異なるチャンネル数や別モジュールを使用する際には変更が必要です．WE7116等の処理マクロがigormacro1にありますが，基本的には同じものです．

取り込んだデータに，Igorの組み込み関数を使用してSFFTを施し周波数スペクトルを作成します．

例えば，測定対象の現象の速さよりオシロのサンプリングが高速過ぎてデータが冗長な時，ファイルサイズを小さくする際に使用します．